SetupWizardWindow.vala

Go to the documentation of this file.

/*
 * SetupWizardWindow.vala
 *
 * Copyright 2012-2018 Tony George <teejeetech@gmail.com>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 */
 
using Gtk;
using Gee;
using Json;
 
using TeeJee.Logging;
using TeeJee.FileSystem;
using TeeJee.JsonHelper;
using TeeJee.ProcessHelper;
using TeeJee.GtkHelper;
using TeeJee.System;
using TeeJee.Misc;
 
class SetupWizardWindow : Gtk.Window {
 
    // Layout
    public signal void request_close();
 
    private Gtk.Box root_box;
    private Gtk.Box sidebar;
    private Gtk.Box content_box;
    private Gtk.Box header_box;
    private Gtk.Box body_box;
    private Gtk.Box actions_box;
    private Gtk.Stack stack;
 
    // Sidebar
    private Gtk.Button btn_nav_import;
    private Gtk.Button btn_nav_backend;
    private Gtk.Button btn_nav_estimate;
    private Gtk.Button btn_nav_location;
    private Gtk.Button btn_nav_schedule;
    private Gtk.Button btn_nav_users;
    private Gtk.Button btn_nav_finish;
    private Gtk.Button? current_nav_btn = null;
 
    // Header titolo pagina
    private Gtk.Label lbl_page_title;
 
    // Pagina import Timeshift
    private Gtk.Box timeshift_page_box;
    private Gtk.Label lbl_timeshift_title;
    private Gtk.Label lbl_timeshift_desc;
    private Gtk.Label lbl_timeshift_found;
    private Gtk.CheckButton radio_import_yes;
    private Gtk.CheckButton radio_import_no;
    private Gtk.Label lbl_timeshift_path;
    private Gtk.Label lbl_timeshift_note;
 
    private bool timeshift_available = false;
    private bool timeshift_import_done = false;
    private int timeshift_backup_count = 0;
    private string timeshift_config_path = "";
 
    // tabs
    private SnapshotBackendBox backend_box;
    private EstimateBox estimate_box;
    private BackupDeviceBox backup_dev_box;
    private FinishBox finish_box;
    private ScheduleBox schedule_box;
    private UsersBox users_box;
    private ExcludeBox exclude_box;
 
    // actions
    private Gtk.Button btn_prev;
    private Gtk.Button btn_next;
    private Gtk.Button btn_cancel;
    private Gtk.Button btn_close;
 
    private bool schedule_accepted = false;
    private bool embedded_mode = false;
 
    private uint tmr_init;
    private int def_width = 980;
    private int def_height = 620;
 
    // Icon reload tracking for theme changes
    private Gee.ArrayList<Gtk.Image> themed_img_list = new Gee.ArrayList<Gtk.Image>();
    private Gee.ArrayList<string>    themed_img_name = new Gee.ArrayList<string>();
    private Gee.ArrayList<int>       themed_img_size = new Gee.ArrayList<int>();
 
    public SetupWizardWindow(bool embedded = false) {
        embedded_mode = embedded;
 
        log_debug("SetupWizardWindow: SetupWizardWindow()");
 
        this.title = _("Setup Wizard");
        if (!embedded_mode) {
            this.modal = true;
        }
        this.set_icon_name("bastionguard-backup");
        if (!embedded_mode)
            this.close_request.connect(on_close_request);
 
        this.set_default_size(def_width, def_height);
        this.set_default_size(def_width, def_height);
        this.set_titlebar(HeaderFactory.create_main_headerbar(this, 220));
 
        if (App.first_run && !schedule_accepted) {
            App.schedule_boot = false;
            App.schedule_hourly = false;
            App.schedule_daily = true;
            log_debug("Setting schedule_daily for first run");
            App.schedule_weekly = false;
            App.schedule_monthly = false;
        }
 
        build_ui();
        build_pages();
        create_actions();
 
        if (!embedded_mode)
            show();
 
        tmr_init = Timeout.add(100, init_delayed);
 
        log_debug("SetupWizardWindow: SetupWizardWindow(): exit");
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // UI
    // ─────────────────────────────────────────────────────────────────────
    private void build_ui() {
 
        root_box = new Gtk.Box(Gtk.Orientation.HORIZONTAL, 0);
        root_box.hexpand = true;
        root_box.vexpand = true;
        root_box.halign = Gtk.Align.FILL;
        root_box.valign = Gtk.Align.FILL;
        set_child(root_box);
 
        build_sidebar();
        build_content();
 
        root_box.append(sidebar);
        root_box.append(content_box);
    }
 
    private void build_sidebar() {
 
        sidebar = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        sidebar.set_size_request(220, -1);
        sidebar.hexpand = false;
        sidebar.vexpand = true;
        sidebar.halign = Gtk.Align.FILL;
        sidebar.valign = Gtk.Align.FILL;
        sidebar.get_style_context().add_class("sidebar");
 
        var sidebar_header = new Gtk.Box(Gtk.Orientation.HORIZONTAL, 8);
        sidebar_header.get_style_context().add_class("sidebar-header");
        sidebar.append(sidebar_header);
 
        Gtk.Widget logo_widget;
        try {
            logo_widget = new Gtk.Image.from_pixbuf(IconManager.lookup("bastionguard-backup", 48));
        }
        catch (Error e) {
            logo_widget = themed_icon("emblem-default-symbolic", 48);
        }
 
        var title = new Gtk.Label("BastionGuard™\nWizard");
        title.xalign = 0.0f;
        title.yalign = 0.5f;
        title.wrap = true;
        title.max_width_chars = 14;
        title.get_style_context().add_class("sidebar-title");
 
        sidebar_header.append(logo_widget);
        sidebar_header.append(title);
 
        sidebar.append(new Gtk.Box(Gtk.Orientation.VERTICAL, 0));
 
        btn_nav_import   = make_nav_button("document-import-symbolic", _("Import"));
        btn_nav_backend  = make_nav_button("document-properties-symbolic", _("Backend"));
        btn_nav_estimate = make_nav_button("system-search-symbolic", _("Estimate"));
        btn_nav_location = make_nav_button("drive-harddisk-symbolic", _("Location"));
        btn_nav_schedule = make_nav_button("x-office-calendar-symbolic", _("Schedule"));
        btn_nav_users    = make_nav_button("system-users-symbolic", _("Users"));
        btn_nav_finish   = make_nav_button("emblem-ok-symbolic", _("Finish"));
 
        btn_nav_import.sensitive   = false;
        btn_nav_backend.sensitive  = false;
        btn_nav_estimate.sensitive = false;
        btn_nav_location.sensitive = false;
        btn_nav_schedule.sensitive = false;
        btn_nav_users.sensitive    = false;
        btn_nav_finish.sensitive   = false;
 
        var spacer = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        spacer.hexpand = true;
        spacer.vexpand = true;
        spacer.halign = Gtk.Align.FILL;
        spacer.valign = Gtk.Align.FILL;
        sidebar.append(spacer);
    }
 
    private Gtk.Button make_nav_button(string icon_name, string label_text) {
 
        var btn = new Gtk.Button();
        btn.get_style_context().add_class("sidebar-button");
                btn.hexpand = true;
        btn.margin_start = 8;
        btn.margin_end = 8;
        btn.margin_top = 2;
        btn.margin_bottom = 2;
 
        var row = new Gtk.Box(Gtk.Orientation.HORIZONTAL, 10);
        row.margin_start = 8;
        row.margin_end = 8;
        row.margin_top = 8;
        row.margin_bottom = 8;
 
        var img = themed_icon(icon_name, 18);
        var lbl = new Gtk.Label(label_text);
        lbl.xalign = 0.0f;
 
        row.append(img);
        row.append(lbl);
 
        btn.set_child(row);
        sidebar.append(btn);
 
        return btn;
    }
 
    private void build_content() {
 
        content_box = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        content_box.get_style_context().add_class("content");
        content_box.hexpand = true;
        content_box.vexpand = true;
        content_box.halign = Gtk.Align.FILL;
        content_box.valign = Gtk.Align.FILL;
 
        header_box = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        header_box.margin_start = 20;
        header_box.margin_end = 20;
        header_box.margin_top = 20;
        header_box.margin_bottom = 10;
 
        lbl_page_title = new Gtk.Label(_("Setup Wizard"));
        lbl_page_title.xalign = 0.0f;
        lbl_page_title.get_style_context().add_class("title");
        header_box.append(lbl_page_title);
 
        body_box = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        body_box.margin_start = 14;
        body_box.margin_end = 14;
        body_box.margin_bottom = 12;
        body_box.hexpand = true;
        body_box.vexpand = true;
        body_box.halign = Gtk.Align.FILL;
        body_box.valign = Gtk.Align.FILL;
 
        stack = new Gtk.Stack();
        stack.transition_type = Gtk.StackTransitionType.CROSSFADE;
        stack.transition_duration = 140;
        stack.hexpand = true;
        stack.vexpand = true;
        stack.halign = Gtk.Align.FILL;
        stack.valign = Gtk.Align.FILL;
 
        body_box.append(stack);
 
        content_box.append(header_box);
        content_box.append(body_box);
    }
 
    private void build_pages() {
 
        build_timeshift_page();
 
        backend_box = new SnapshotBackendBox(this);
        backend_box.margin_start = 12;
        backend_box.margin_end = 12;
        backend_box.margin_top = 12;
        backend_box.margin_bottom = 12;
 
        estimate_box = new EstimateBox(this);
        estimate_box.margin_start = 12;
        estimate_box.margin_end = 12;
        estimate_box.margin_top = 12;
        estimate_box.margin_bottom = 12;
 
        backup_dev_box = new BackupDeviceBox(this);
        backup_dev_box.margin_start = 12;
        backup_dev_box.margin_end = 12;
        backup_dev_box.margin_top = 12;
        backup_dev_box.margin_bottom = 12;
 
        schedule_box = new ScheduleBox(this);
        schedule_box.margin_start = 12;
        schedule_box.margin_end = 12;
        schedule_box.margin_top = 12;
        schedule_box.margin_bottom = 12;
 
        exclude_box = new ExcludeBox(this);
        users_box = new UsersBox(this, exclude_box, false);
        users_box.margin_start = 12;
        users_box.margin_end = 12;
        users_box.margin_top = 12;
        users_box.margin_bottom = 12;
 
        finish_box = new FinishBox(this, false);
        finish_box.margin_start = 12;
        finish_box.margin_end = 12;
        finish_box.margin_top = 12;
        finish_box.margin_bottom = 12;
 
        var page_import   = wrap_page(timeshift_page_box);
        var page_backend  = wrap_page(backend_box);
        var page_estimate = wrap_page(estimate_box);
        var page_location = wrap_page(backup_dev_box);
        var page_schedule = wrap_page(schedule_box);
        var page_users    = wrap_page(users_box);
        var page_finish   = wrap_page(finish_box);
 
        stack.add_named(page_import, "import");
        stack.add_named(page_backend, "backend");
        stack.add_named(page_estimate, "estimate");
        stack.add_named(page_location, "location");
        stack.add_named(page_schedule, "schedule");
        stack.add_named(page_users, "users");
        stack.add_named(page_finish, "finish");
    }
 
    private void build_timeshift_page() {
 
        timeshift_page_box = new Gtk.Box(Gtk.Orientation.VERTICAL, 12);
        timeshift_page_box.margin_start = 18;
        timeshift_page_box.margin_end = 18;
        timeshift_page_box.margin_top = 18;
        timeshift_page_box.margin_bottom = 18;
        timeshift_page_box.hexpand = true;
        timeshift_page_box.vexpand = true;
 
        lbl_timeshift_title = new Gtk.Label(_("Do you want to import from Timeshift?"));
        lbl_timeshift_title.xalign = 0.0f;
        lbl_timeshift_title.get_style_context().add_class("h1");
 
        lbl_timeshift_desc = new Gtk.Label(
            _("If a Timeshift configuration is present on this system, BastionGuard can import compatible settings and detect existing backups without modifying or deleting the original data.")
        );
        lbl_timeshift_desc.xalign = 0.0f;
        lbl_timeshift_desc.wrap = true;
        lbl_timeshift_desc.max_width_chars = 80;
 
        lbl_timeshift_found = new Gtk.Label("");
        lbl_timeshift_found.xalign = 0.0f;
        lbl_timeshift_found.wrap = true;
 
        lbl_timeshift_path = new Gtk.Label("");
        lbl_timeshift_path.xalign = 0.0f;
        lbl_timeshift_path.wrap = true;
        lbl_timeshift_path.selectable = true;
 
        radio_import_yes = new Gtk.CheckButton.with_label(_("Yes, import from Timeshift"));
        radio_import_no  = new Gtk.CheckButton.with_label(_("No, configure manually"));
        radio_import_no.set_group(radio_import_yes);
 
        lbl_timeshift_note = new Gtk.Label(
            _("Import copies only compatible settings into BastionGuard. Original Timeshift files are not modified.")
        );
        lbl_timeshift_note.xalign = 0.0f;
        lbl_timeshift_note.wrap = true;
        lbl_timeshift_note.max_width_chars = 80;
 
        timeshift_page_box.append(lbl_timeshift_title);
        timeshift_page_box.append(lbl_timeshift_desc);
        timeshift_page_box.append(new Gtk.Separator(Gtk.Orientation.HORIZONTAL));
        timeshift_page_box.append(lbl_timeshift_found);
        timeshift_page_box.append(lbl_timeshift_path);
        timeshift_page_box.append(new Gtk.Box(Gtk.Orientation.VERTICAL, 0));
        timeshift_page_box.append(radio_import_yes);
        timeshift_page_box.append(radio_import_no);
        timeshift_page_box.append(new Gtk.Box(Gtk.Orientation.VERTICAL, 0));
        timeshift_page_box.append(lbl_timeshift_note);
    }
 
    private Gtk.Widget wrap_page(Gtk.Widget child) {
        var card = new Gtk.Box(Gtk.Orientation.VERTICAL, 0);
        card.get_style_context().add_class("card");
        card.hexpand = true;
        card.vexpand = true;
        card.margin_start = 6;
        card.margin_end = 6;
        card.margin_top = 6;
        card.margin_bottom = 6;
        card.append(child);
        return card;
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // TIMESHiFT DETECTION
    // ─────────────────────────────────────────────────────────────────────
    private void detect_timeshift_state() {
 
        timeshift_available = false;
        timeshift_backup_count = 0;
        timeshift_config_path = "";
 
        string[] candidate_paths = {
            "/etc/timeshift/timeshift.json",
            "/etc/timeshift.json"
        };
 
        foreach (string path in candidate_paths) {
            if (file_exists(path)) {
                timeshift_available = true;
                timeshift_config_path = path;
                break;
            }
        }
 
        if (timeshift_available) {
            timeshift_backup_count = probe_timeshift_snapshot_count(timeshift_config_path);
            return;
        }
 
        timeshift_backup_count = probe_timeshift_snapshots_from_mounts();
        if (timeshift_backup_count > 0) {
            timeshift_available = true;
        }
    }
 
    private int probe_timeshift_snapshots_from_mounts() {
 
        int count = 0;
        var all_devices = Device.get_block_devices_using_lsblk();
 
        foreach (var dev in all_devices) {
 
            if (dev.uuid.length == 0) continue;
            if (dev.fstype != "ext4" && dev.fstype != "ext3"
                && dev.fstype != "btrfs" && dev.fstype != "xfs") continue;
 
            var tmp_repo = new SnapshotRepo.from_uuid(dev.uuid, this, dev.fstype == "btrfs");
            if (tmp_repo == null) continue;
            if (tmp_repo.mount_path.length == 0) continue;
 
            string[] snap_dirs = {
                path_combine(tmp_repo.mount_path, "timeshift/snapshots"),
                path_combine(tmp_repo.mount_path, "timeshift-btrfs/snapshots"),
                path_combine(tmp_repo.mount_path, "bastionguard-backup/snapshots"),
                path_combine(tmp_repo.mount_path, "bastionguard-backup-btrfs/snapshots")
            };
 
            foreach (var snap_dir in snap_dirs) {
                if (!dir_exists(snap_dir)) continue;
 
                try {
                    var dir = File.new_for_path(snap_dir);
                    var enumerator = dir.enumerate_children("standard::name,standard::type", 0);
                    var info = enumerator.next_file();
 
                    while (info != null) {
                        if (info.get_file_type() == FileType.DIRECTORY
                            && info.get_name() != ".sync") {
                            count++;
                            }
                            info = enumerator.next_file();
                    }
                }
                catch {}
 
                if (count > 0) {
                    if (App.backup_uuid.length == 0)
                        App.backup_uuid = dev.uuid;
                    break;
                }
            }
 
            if (count > 0) break;
        }
 
        return count;
    }
 
    private int probe_timeshift_snapshot_count(string config_path) {
 
        try {
            var parser = new Json.Parser();
            parser.load_from_file(config_path);
 
            Json.Node? node = parser.get_root();
            Json.Object config = node?.get_object() ?? new Json.Object();
 
            string backup_uuid = json_get_string(config, "backup_device_uuid", "");
            string parent_uuid = json_get_string(config, "parent_device_uuid", "");
            bool tmp_btrfs_mode = json_get_bool(config, "btrfs_mode", false);
 
            SnapshotRepo tmp_repo = null;
 
            if (backup_uuid.length > 0) {
                tmp_repo = new SnapshotRepo.from_uuid(backup_uuid, this, tmp_btrfs_mode);
            }
            else if (parent_uuid.length > 0) {
                tmp_repo = new SnapshotRepo.from_uuid(parent_uuid, this, tmp_btrfs_mode);
            }
 
            if (tmp_repo == null) {
                return 0;
            }
 
            tmp_repo.load_snapshots();
            return tmp_repo.snapshots.size;
        }
        catch (Error e) {
            log_error("probe_timeshift_snapshot_count(): " + e.message);
            return 0;
        }
    }
 
    private void refresh_timeshift_page() {
 
        if (!timeshift_available) {
            lbl_timeshift_found.label = _("No Timeshift configuration or backup was detected.");
            lbl_timeshift_path.label = "";
            radio_import_yes.sensitive = false;
            radio_import_no.active = true;
            return;
        }
 
        if (timeshift_config_path.length > 0) {
            lbl_timeshift_path.label = _("Configuration found") + ": " + timeshift_config_path;
        }
        else if (App.backup_uuid.length > 0) {
            lbl_timeshift_path.label = _("Backups detected on device UUID") + ": " + App.backup_uuid;
        }
        else {
            lbl_timeshift_path.label = _("Timeshift backups detected by scanning available devices.");
        }
 
        if (timeshift_config_path.length > 0) {
            if (timeshift_backup_count == 0) {
                lbl_timeshift_found.label = _("Timeshift configuration found, but no importable backup was detected.");
            }
            else if (timeshift_backup_count == 1) {
                lbl_timeshift_found.label = _("Timeshift configuration found. 1 backup was detected.");
            }
            else {
                lbl_timeshift_found.label = _("Timeshift configuration found. %d backups were detected.").printf(timeshift_backup_count);
            }
        }
        else {
            if (timeshift_backup_count == 1) {
                lbl_timeshift_found.label = _("1 Timeshift backup was detected, but no Timeshift configuration file was found.");
            }
            else {
                lbl_timeshift_found.label = _("%d Timeshift backups were detected, but no Timeshift configuration file was found.").printf(timeshift_backup_count);
            }
        }
 
        radio_import_yes.sensitive = true;
 
        if (!timeshift_import_done) {
            radio_import_yes.active = true;
        }
    }
 
    private bool should_import_timeshift() {
        return timeshift_available && radio_import_yes.active;
    }
 
    private bool run_timeshift_import() {
 
        if (!should_import_timeshift()) {
            return true;
        }
 
        if (timeshift_import_done) {
            return true;
        }
 
        if (timeshift_config_path.length == 0) {
            timeshift_import_done = true;
 
            App.initialize_repo();
            if (App.repo != null) {
                App.repo.load_snapshots();
            }
 
            gtk_messagebox(
                _("Backup repository detected"),
                           _("Existing Timeshift backups were detected and will be used, but no Timeshift configuration file was found to import settings from."),
                           this,
                  false
            );
 
            return true;
        }
 
        if (!App.import_timeshift_config_if_available()) {
            gtk_messagebox(
                _("Import failed"),
                           _("The Timeshift configuration could not be imported. BastionGuard may already have its own configuration, or the Timeshift configuration file may be invalid."),
                           this,
                  true
            );
            return false;
        }
 
        timeshift_import_done = true;
 
        App.initialize_repo();
        if (App.repo != null) {
            App.repo.load_snapshots();
        }
 
        gtk_messagebox(
            _("Import completed"),
                       _("Timeshift settings were imported successfully into BastionGuard."),
                       this,
                 false
        );
 
        return true;
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // ACTIONS
    // ─────────────────────────────────────────────────────────────────────
    private void create_actions() {
 
        actions_box = new Gtk.Box(Gtk.Orientation.HORIZONTAL, 8);
        actions_box.margin_start = 20;
        actions_box.margin_end = 20;
        actions_box.margin_bottom = 20;
        actions_box.halign = Gtk.Align.END;
 
        btn_prev = new Gtk.Button.with_label(_("Previous"));
        btn_next = new Gtk.Button.with_label(_("Next"));
        btn_close = new Gtk.Button.with_label(_("Finish"));
        btn_cancel = new Gtk.Button.with_label(_("Cancel"));
        btn_prev.set_size_request(110, -1);
        btn_next.set_size_request(110, -1);
        btn_close.set_size_request(110, -1);
        btn_cancel.set_size_request(110, -1);
 
        // CSS styling for nav buttons
        btn_prev.get_style_context().add_class("btn-back");
        btn_next.get_style_context().add_class("btn-next");
        btn_close.get_style_context().add_class("btn-finish");
        btn_close.get_style_context().add_class("suggested-action");
        btn_cancel.get_style_context().add_class("btn-cancel");
 
        btn_prev.clicked.connect(() => { go_prev(); });
        btn_next.clicked.connect(() => { go_next(); });
        btn_close.clicked.connect(() => {
            save_changes();
            if (embedded_mode) request_close();
            else this.destroy();
        });
        btn_cancel.clicked.connect(() => {
            if (App.task != null) {
                App.task.stop(AppStatus.CANCELLED);
            }
            if (embedded_mode) request_close();
            else this.destroy();
        });
 
        actions_box.append(btn_cancel);
        actions_box.append(btn_prev);
        actions_box.append(btn_next);
        actions_box.append(btn_close);
 
        content_box.append(actions_box);
 
        action_buttons_set_initial_visibility(false);
    }
 
    private void action_buttons_set_initial_visibility(bool visible) {
        btn_prev.visible = visible;
        btn_next.visible = visible;
        btn_close.visible = visible;
        btn_cancel.visible = visible;
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // INIT
    // ─────────────────────────────────────────────────────────────────────
    private bool init_delayed() {
 
        if (tmr_init > 0) {
            Source.remove(tmr_init);
            tmr_init = 0;
        }
 
        detect_timeshift_state();
        refresh_timeshift_page();
 
        this.set_default_size(def_width, def_height);
        go_first();
 
        return false;
    }
 
    private bool on_close_request() {
 
        if (App.first_run && !schedule_accepted) {
            App.schedule_boot = false;
            App.schedule_hourly = false;
            App.schedule_daily = false;
            App.schedule_weekly = false;
            App.schedule_monthly = false;
        }
 
        save_changes();
        return false;
    }
 
    private void save_changes() {
        App.cron_job_update();
        App.first_run = false;
    }
 
    public Gtk.Widget detach_root_widget() {
        set_child(null);
        return root_box;
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // NAVIGATION
    // ─────────────────────────────────────────────────────────────────────
    private void go_first() {
        set_page(Tabs.IMPORT_TIMESHIFT);
        initialize_tab();
    }
 
    private void go_prev() {
 
        switch (get_current_tab()) {
            case Tabs.IMPORT_TIMESHIFT:
                break;
            case Tabs.SNAPSHOT_BACKEND:
                set_page(Tabs.IMPORT_TIMESHIFT);
                break;
            case Tabs.ESTIMATE:
                set_page(Tabs.SNAPSHOT_BACKEND);
                break;
            case Tabs.BACKUP_DEVICE:
                if (App.btrfs_mode) {
                    set_page(Tabs.SNAPSHOT_BACKEND);
                }
                else {
                    set_page(Tabs.ESTIMATE);
                }
                break;
            case Tabs.SCHEDULE:
                set_page(Tabs.BACKUP_DEVICE);
                break;
            case Tabs.USERS:
                set_page(Tabs.SCHEDULE);
                break;
            case Tabs.FINISH:
                set_page(Tabs.USERS);
                break;
        }
 
        initialize_tab();
    }
 
    private void go_next() {
 
        if (!validate_current_tab()) {
            return;
        }
 
        switch (get_current_tab()) {
 
            case Tabs.IMPORT_TIMESHIFT:
                if (!run_timeshift_import()) {
                    return;
                }
                set_page(Tabs.SNAPSHOT_BACKEND);
                break;
 
            case Tabs.SNAPSHOT_BACKEND:
                if (App.btrfs_mode) {
                    set_page(Tabs.BACKUP_DEVICE);
                }
                else {
                    set_page(Tabs.ESTIMATE);
                }
                break;
 
            case Tabs.ESTIMATE:
                set_page(Tabs.BACKUP_DEVICE);
                break;
 
            case Tabs.BACKUP_DEVICE:
                if (App.live_system()) {
                    destroy();
                    return;
                }
                else {
                    set_page(Tabs.SCHEDULE);
                }
                break;
 
            case Tabs.SCHEDULE:
                set_page(Tabs.USERS);
                schedule_accepted = true;
                break;
 
            case Tabs.USERS:
                set_page(Tabs.FINISH);
                break;
 
            case Tabs.FINISH:
                break;
        }
 
        initialize_tab();
    }
 
    private void initialize_tab() {
 
        switch (get_current_tab()) {
 
            case Tabs.IMPORT_TIMESHIFT:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = false;
                btn_next.sensitive = true;
                btn_close.sensitive = true;
 
                refresh_timeshift_page();
                break;
 
            case Tabs.SNAPSHOT_BACKEND:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = true;
                btn_next.sensitive = true;
                btn_close.sensitive = true;
 
                backend_box.refresh();
                break;
 
            case Tabs.ESTIMATE:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = false;
                btn_next.sensitive = false;
                btn_close.sensitive = false;
 
                if (App.btrfs_mode) {
                    go_next();
                    return;
                }
                else {
                    estimate_box.estimate_system_size();
                    go_next();
                    return;
                }
 
            case Tabs.BACKUP_DEVICE:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = true;
                btn_next.sensitive = true;
                btn_close.sensitive = true;
 
                backup_dev_box.refresh();
                break;
 
            case Tabs.SCHEDULE:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = true;
                btn_next.sensitive = true;
                btn_close.sensitive = true;
 
                schedule_box.update_statusbar();
                break;
 
            case Tabs.USERS:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = true;
                btn_next.sensitive = true;
                btn_close.sensitive = true;
 
                users_box.refresh();
                break;
 
            case Tabs.FINISH:
                btn_prev.show();
                btn_next.show();
                btn_close.show();
                btn_cancel.hide();
 
                btn_prev.sensitive = false;
                btn_next.sensitive = false;
                btn_close.sensitive = true;
 
                finish_box.refresh();
                break;
        }
 
        update_sidebar_state();
        update_page_title();
    }
 
    private bool validate_current_tab() {
 
        if (get_current_tab() == Tabs.IMPORT_TIMESHIFT) {
            return true;
        }
        else if (get_current_tab() == Tabs.SNAPSHOT_BACKEND) {
            return true;
        }
        else if (get_current_tab() == Tabs.BACKUP_DEVICE) {
            if (!App.repo.available() || !App.repo.has_space()) {
                gtk_messagebox(
                    App.repo.status_message,
                   App.repo.status_details,
                   this,
                   true
                );
                return false;
            }
        }
 
        return true;
    }
 
    // ─────────────────────────────────────────────────────────────────────
    // PAGE STATE
    // ─────────────────────────────────────────────────────────────────────
    private Tabs current_tab = Tabs.IMPORT_TIMESHIFT;
 
    private void set_page(Tabs tab) {
        current_tab = tab;
 
        switch (tab) {
            case Tabs.IMPORT_TIMESHIFT:
                stack.set_visible_child_name("import");
                break;
            case Tabs.SNAPSHOT_BACKEND:
                stack.set_visible_child_name("backend");
                break;
            case Tabs.ESTIMATE:
                stack.set_visible_child_name("estimate");
                break;
            case Tabs.BACKUP_DEVICE:
                stack.set_visible_child_name("location");
                break;
            case Tabs.SCHEDULE:
                stack.set_visible_child_name("schedule");
                break;
            case Tabs.USERS:
                stack.set_visible_child_name("users");
                break;
            case Tabs.FINISH:
                stack.set_visible_child_name("finish");
                break;
        }
    }
 
    private Tabs get_current_tab() {
        return current_tab;
    }
 
    private void update_sidebar_state() {
 
        clear_sidebar_selection();
 
        switch (current_tab) {
            case Tabs.IMPORT_TIMESHIFT:
                set_sidebar_active(btn_nav_import);
                break;
            case Tabs.SNAPSHOT_BACKEND:
                set_sidebar_active(btn_nav_backend);
                break;
            case Tabs.ESTIMATE:
                set_sidebar_active(btn_nav_estimate);
                break;
            case Tabs.BACKUP_DEVICE:
                set_sidebar_active(btn_nav_location);
                break;
            case Tabs.SCHEDULE:
                set_sidebar_active(btn_nav_schedule);
                break;
            case Tabs.USERS:
                set_sidebar_active(btn_nav_users);
                break;
            case Tabs.FINISH:
                set_sidebar_active(btn_nav_finish);
                break;
        }
    }
 
    private void update_page_title() {
        switch (current_tab) {
            case Tabs.IMPORT_TIMESHIFT:
                lbl_page_title.label = _("Import from Timeshift");
                break;
            case Tabs.SNAPSHOT_BACKEND:
                lbl_page_title.label = _("Backend");
                break;
            case Tabs.ESTIMATE:
                lbl_page_title.label = _("Estimate");
                break;
            case Tabs.BACKUP_DEVICE:
                lbl_page_title.label = _("Location");
                break;
            case Tabs.SCHEDULE:
                lbl_page_title.label = _("Schedule");
                break;
            case Tabs.USERS:
                lbl_page_title.label = _("Users");
                break;
            case Tabs.FINISH:
                lbl_page_title.label = _("Finish");
                break;
        }
    }
 
    private void clear_sidebar_selection() {
        btn_nav_import.get_style_context().remove_class("active-sidebar-button");
        btn_nav_backend.get_style_context().remove_class("active-sidebar-button");
        btn_nav_estimate.get_style_context().remove_class("active-sidebar-button");
        btn_nav_location.get_style_context().remove_class("active-sidebar-button");
        btn_nav_schedule.get_style_context().remove_class("active-sidebar-button");
        btn_nav_users.get_style_context().remove_class("active-sidebar-button");
        btn_nav_finish.get_style_context().remove_class("active-sidebar-button");
    }
 
    private void set_sidebar_active(Gtk.Button btn) {
        btn.get_style_context().add_class("active-sidebar-button");
        current_nav_btn = btn;
    }
 
    public enum Tabs {
        IMPORT_TIMESHIFT = 0,
        SNAPSHOT_BACKEND = 1,
        ESTIMATE = 2,
        BACKUP_DEVICE = 3,
        SCHEDULE = 4,
        USERS = 5,
        FINISH = 6
    }
 
    // ── Icon theme support ──────────────────────────────────────────────
    private Gtk.Image themed_icon(string icon_name, int size) {
        var img = IconManager.lookup_image(icon_name, size);
        themed_img_list.add(img);
        themed_img_name.add(icon_name);
        themed_img_size.add(size);
        return img;
    }
 
    public void reload_themed_icons() {
        for (int i = 0; i < themed_img_list.size; i++) {
            var img  = themed_img_list[i];
            var name = themed_img_name[i];
            var sz   = themed_img_size[i];
            var pix  = IconManager.lookup(name, sz);
            if (pix != null) {
                img.set_from_pixbuf(pix);
            } else {
                img.set_from_icon_name(name);
            }
        }
    }
 
 
}