IconManager.vala

Go to the documentation of this file.

/*
 * IconManager.vala
 *
 * Copyright 2012-2018 Tony George <teejeetech@gmail.com>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
 * MA 02110-1301, USA.
 *
 *
 */
 
 
using Gtk;
using Gee;
using Cairo;
 
using TeeJee.Logging;
using TeeJee.FileSystem;
using TeeJee.JsonHelper;
using TeeJee.ProcessHelper;
using TeeJee.GtkHelper;
using TeeJee.System;
using TeeJee.Misc;
 
public class IconManager : GLib.Object {
 
    public static Gtk.IconTheme theme;
 
    public static Gee.ArrayList<string> search_paths = new Gee.ArrayList<string>();
 
    // Set this to true when dark theme is active so lookup_image uses white icons,
    // false for light theme (black icons). Updated by MainWindow.load_css().
    public static bool use_dark = false;
 
    public const int SHIELD_ICON_SIZE = 64;
 
    public const string GENERIC_ICON_IMAGE = "image-x-generic";
    public const string GENERIC_ICON_IMAGE_MISSING = "image-missing";
    public const string GENERIC_ICON_VIDEO = "video-x-generic";
    public const string GENERIC_ICON_FILE = "text-x-preview";
    public const string GENERIC_ICON_ARCHIVE_FILE = "package-x-generic";
    public const string GENERIC_ICON_DIRECTORY = "folder";
    public const string GENERIC_ICON_ISO = "media-cdrom";
    public const string GENERIC_ICON_PDF = "application-pdf";
 
    public const string ICON_HARDDRIVE = "drive-harddisk";
 
    public const string SHIELD_LIVE= "media-optical";
    public const string SHIELD_LOW = "bastionguard-backup-shield-low";
    public const string SHIELD_MED = "bastionguard-backup-shield-med";
    public const string SHIELD_HIGH = "bastionguard-backup-shield-high";
 
    public static void init(string[] args, string app_name){
 
        log_debug("IconManager: init()");
        
        search_paths = new Gee.ArrayList<string>();
 
        string[] extra_paths = {
            "/usr/share/%s/images-dark".printf(app_name),
            "/usr/share/%s/images-light".printf(app_name),
            "/usr/local/share/%s/images-dark".printf(app_name),
            "/usr/local/share/%s/images-light".printf(app_name),
            "/usr/share/%s/images".printf(app_name),
            "/usr/local/share/%s/images".printf(app_name),
            "/usr/share/pixmaps",
            "/usr/local/share/pixmaps",
            GLib.Path.build_filename(GLib.Environment.get_user_data_dir(), app_name, "images-dark"),
            GLib.Path.build_filename(GLib.Environment.get_user_data_dir(), app_name, "images-light"),
            GLib.Path.build_filename(GLib.Environment.get_user_data_dir(), app_name, "images"),
            GLib.Path.build_filename(GLib.Environment.get_current_dir(), "src", "share", app_name, "images-dark"),
            GLib.Path.build_filename(GLib.Environment.get_current_dir(), "src", "share", app_name, "images-light"),
            GLib.Path.build_filename(GLib.Environment.get_current_dir(), "src", "share", app_name, "images"),
            GLib.Path.build_filename(GLib.Environment.get_current_dir(), "src", "share", "pixmaps"),
            GLib.Path.build_filename(GLib.Environment.get_current_dir(), "icons")
        };
        foreach (var path in extra_paths) {
            if (dir_exists(path) && !search_paths.contains(path)) {
                search_paths.add(path);
                log_debug("found images directory: %s".printf(path));
            }
        }
 
        refresh_icon_theme();
    }
 
    public static void refresh_icon_theme(){
 
        if (!GTK_INITIALIZED) { return; }
        
        var display = Gdk.Display.get_default();
        if (display == null) { return; }
        theme = Gtk.IconTheme.get_for_display(display);
        foreach(string path in search_paths){
            theme.add_search_path(path);
        }
    }
 
    public static Gdk.Pixbuf? lookup(string icon_name, int icon_size, bool symbolic = false, bool use_hardcoded = false, int scale = 1){
        // Pick the theme-specific subfolder first (images-dark/ or images-light/)
        string theme_folder = use_dark ? "images-dark" : "images-light";
        string[] resource_candidates = {
            "images/" + theme_folder + "/" + icon_name + ".svg",
            "images/" + theme_folder + "/" + icon_name + ".png",
            "images/" + icon_name + ".png",
            "images/" + icon_name + ".svg",
            "images/" + icon_name,
            "icons/" + icon_name + ".png",
            "pixmaps/" + icon_name + ".png",
            "icons/hicolor/128x128/apps/" + icon_name + ".png",
            "icons/hicolor/96x96/apps/" + icon_name + ".png",
            "icons/hicolor/64x64/apps/" + icon_name + ".png",
            "icons/hicolor/48x48/apps/" + icon_name + ".png",
            "icons/hicolor/32x32/apps/" + icon_name + ".png",
            "icons/hicolor/24x24/apps/" + icon_name + ".png",
            "icons/hicolor/22x22/apps/" + icon_name + ".png",
            "icons/hicolor/16x16/apps/" + icon_name + ".png"
        };
 
        Gdk.Pixbuf? pixbuf = null;
        if (icon_name.length == 0){ return null; }
 
        foreach (var rel in resource_candidates) {
            if (ResourceHelper.resource_exists(rel)) {
                try {
                    pixbuf = new Gdk.Pixbuf.from_resource_at_scale(ResourceHelper.resource_prefix() + "/" + rel, icon_size, icon_size, true);
                    if (pixbuf != null) return pixbuf;
                } catch (Error e) {
                    // ignore and continue with filesystem fallback
                }
            }
        }
 
        string? resolved = ResourceHelper.resolve_icon_file(icon_name);
        if (resolved != null) {
            pixbuf = load_pixbuf_from_file(resolved, icon_size);
            if (pixbuf != null) return pixbuf;
        }
 
        foreach(string search_path in search_paths){
            foreach(string ext in new string[] { ".svg", ".png", ".jpg", ".gif"}){
                string img_file = path_combine(search_path, icon_name + ext);
                if (file_exists(img_file)){
                    pixbuf = load_pixbuf_from_file(img_file, icon_size);
                    if (pixbuf != null){ return pixbuf; }
                }
            }
        }
 
        return null;
    }
    
    
    public static Gdk.Pixbuf? lookup_gicon(GLib.Icon gicon, int icon_size){
        return lookup(GENERIC_ICON_FILE, icon_size, false);
    }
 
    
public static Gtk.Image lookup_image(string icon_name, int icon_size, bool symbolic = false, bool use_hardcoded = false){
 
        var image = new Gtk.Image();
        image.set_pixel_size(icon_size);
        if (icon_name.length == 0){
            image.set_from_icon_name(GENERIC_ICON_IMAGE_MISSING);
            return image;
        }
 
        Gdk.Pixbuf? pix = lookup(icon_name, icon_size, symbolic, use_hardcoded, image.get_scale_factor());
        if (pix != null){
            image.set_from_pixbuf(pix);
        } else {
            image.set_from_icon_name(icon_name);
        }
        return image;
    }
 
    public static Gtk.Button button_from_icon(string icon_name, int icon_size, string? tooltip = null){
        var btn = new Gtk.Button();
        btn.set_child(lookup_image(icon_name, icon_size));
        if (tooltip != null) btn.tooltip_text = tooltip;
        return btn;
    }
 
    public static Cairo.Surface? lookup_surface(string icon_name, int icon_size, int scale = 1, bool symbolic = false, bool use_hardcoded = false){
        return null;
    }
 
    public static Gdk.Pixbuf? add_emblem (Gdk.Pixbuf pixbuf, string icon_name, int emblem_size, bool emblem_symbolic, Gtk.CornerType corner_type) {
 
        if (icon_name.length == 0){ return pixbuf; }
 
        Gdk.Pixbuf? emblem = null;
 
        var SMALL_EMBLEM_COLOR = Gdk.RGBA();
        SMALL_EMBLEM_COLOR.parse("#000000");
        SMALL_EMBLEM_COLOR.alpha = 1.0f;
 
        var EMBLEM_PADDING = 1;
 
        emblem = lookup(icon_name, emblem_size, emblem_symbolic, true);
        if (emblem == null) {
            return pixbuf;
        }
 
        if (emblem == null)
            return pixbuf;
 
        var offset_x = EMBLEM_PADDING;
 
        if ((corner_type == Gtk.CornerType.BOTTOM_RIGHT) || (corner_type == Gtk.CornerType.TOP_RIGHT)){
            offset_x = pixbuf.width - emblem.width - EMBLEM_PADDING ;
        }
 
        var offset_y = EMBLEM_PADDING;
 
        if ((corner_type == Gtk.CornerType.BOTTOM_LEFT) || (corner_type == Gtk.CornerType.BOTTOM_RIGHT)){
            offset_y = pixbuf.height - emblem.height - EMBLEM_PADDING ;
        }
 
        var emblemed = pixbuf.copy();
        
        emblem.composite(emblemed, 
            offset_x, offset_y, 
            emblem_size, emblem_size,
            offset_x, offset_y, 
            1.0, 1.0, 
            Gdk.InterpType.BILINEAR, 255);
 
        return emblemed;
    }
    
    public static Gdk.Pixbuf? add_overlay(Gdk.Pixbuf pixbuf_base, Gdk.Pixbuf pixbuf_overlay) {
 
        int offset_x = (pixbuf_base.width - pixbuf_overlay.width) / 2 ;
 
        var offset_y = (pixbuf_base.height - pixbuf_overlay.height) / 2 ;
 
        var emblemed = pixbuf_base.copy();
        
        pixbuf_overlay.composite(emblemed, 
            offset_x, offset_y, 
            pixbuf_overlay.width, pixbuf_overlay.height,
            offset_x, offset_y, 
            1.0, 1.0, 
            Gdk.InterpType.BILINEAR, 255);
 
        return emblemed;
    }
    
    public static Gdk.Pixbuf? resize_icon(Gdk.Pixbuf pixbuf_image, int icon_size) {
        
        //log_debug("resize_icon()");
        
        var pixbuf_empty = new Gdk.Pixbuf(Gdk.Colorspace.RGB, true, 8, icon_size, icon_size);
        pixbuf_empty.fill(0x00000000);
 
        //log_debug("pixbuf_empty: %d, %d".printf(pixbuf_empty.width, pixbuf_empty.height));
        
        var pixbuf_resized = add_overlay(pixbuf_empty, pixbuf_image);
        
        //log_debug("pixbuf_resized: %d, %d".printf(pixbuf_resized.width, pixbuf_resized.height));
 
        //copy_pixbuf_options(pixbuf_image, pixbuf_resized);
        
        return pixbuf_resized;
    }
    
    public static Gdk.Pixbuf? add_transparency (Gdk.Pixbuf pixbuf, int opacity = 130) {
 
        var trans = pixbuf.copy();
        trans.fill((uint32) 0xFFFFFF00);
 
        //log_debug("add_transparency");
 
        int width = pixbuf.get_width();
        int height = pixbuf.get_height();
        pixbuf.composite(trans, 0, 0, width, height, 0, 0, 1.0, 1.0, Gdk.InterpType.BILINEAR, opacity);
 
        return trans;
    }
    
    public static Gdk.Pixbuf? load_pixbuf_from_file(string file_path, int icon_size){
        
        Gdk.Pixbuf? pixbuf = null;
        
        int width, height;
        Gdk.Pixbuf.get_file_info(file_path, out width, out height);
        
        if ((width <= icon_size) && (height <= icon_size)){
            try{
                // load without scaling
                pixbuf = new Gdk.Pixbuf.from_file(file_path);
                // pad to requested size
                pixbuf = resize_icon(pixbuf, icon_size);
                // return
                if (pixbuf != null){ return pixbuf; }
            }
            catch (Error e){
                // ignore
            }
        }
        else {
            try{
                // load with scaling - scale down to requested box
                pixbuf = new Gdk.Pixbuf.from_file_at_scale(file_path, icon_size, icon_size, true);
                // pad to requested size
                pixbuf = resize_icon(pixbuf, icon_size);
                // return
                if (pixbuf != null){ return pixbuf; }
            }
            catch (Error e){
                // ignore
            }
        }
        
        return null;
    }
}