DeleteWindow.vala

Go to the documentation of this file.

/*
 * DeleteWindow.vala
 *
 * Copyright 2012-2018 Tony George <teejeetech@gmail.com>
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
 * MA 02110-1301, USA.
 *
 *
 */
 
using Gtk;
using Gee;
 
using TeeJee.Logging;
using TeeJee.FileSystem;
using TeeJee.JsonHelper;
using TeeJee.ProcessHelper;
using TeeJee.GtkHelper;
using TeeJee.System;
using TeeJee.Misc;
 
class DeleteWindow : Gtk.Window{
 
    public signal void request_close();
    
    private Gtk.Box vbox_main;
    private Gtk.Stack page_stack;
    private int current_page = -1;
    private Gtk.Box bbox_action;
 
    // tabs
    private SnapshotListBox snapshot_list_box;
    private DeleteBox delete_box;
    private DeleteFinishBox delete_finish_box;
 
    // actions
    private Gtk.Button btn_prev;
    private Gtk.Button btn_next;
    private Gtk.Button btn_hide;
    private Gtk.Button btn_cancel;
    private Gtk.Button btn_close;
 
    private uint tmr_init;
    private int def_width = 500;
    private int def_height = 500;
    private bool success = false;
    private bool embedded_mode = false;
    
    public DeleteWindow(bool embedded = false) {
        embedded_mode = embedded;
 
        log_debug("DeleteWindow: DeleteWindow()");
        
        this.title = _("Delete Snapshots");
        if (!embedded_mode) this.modal = true;
        this.set_default_size (def_width, def_height);
        this.set_icon_name("bastionguard-backup");
 
        if (!embedded_mode) this.close_request.connect(on_close_request);
 
        this.set_default_size(def_width, def_height);
        
        // vbox_main
        vbox_main = new Gtk.Box(Orientation.VERTICAL, 6);
        vbox_main.margin_start = 0;
        vbox_main.margin_end = 0;
        vbox_main.margin_top = 0;
        vbox_main.margin_bottom = 0;
        set_child(vbox_main);
 
        page_stack = new Gtk.Stack();
        page_stack.hexpand = true;
        page_stack.vexpand = true;
        vbox_main.append(page_stack);
 
        // create tab
        
        var vbox_tab = new Gtk.Box(Orientation.VERTICAL, 6);
        vbox_tab.margin_start = 12;
        vbox_tab.margin_end = 12;
        vbox_tab.margin_top = 12;
        vbox_tab.margin_bottom = 12;
        
        add_label_header(vbox_tab, _("Select Snapshots"), true);
 
        add_label(vbox_tab, _("Select the snapshots to be deleted"));
        
        var label = new Gtk.Label(_("Snapshots"));
        
        snapshot_list_box = new SnapshotListBox(this);
        snapshot_list_box.hide_context_menu();
        snapshot_list_box.margin_start = 0;
        snapshot_list_box.margin_end = 0;
        snapshot_list_box.margin_top = 0;
        snapshot_list_box.margin_bottom = 0;
        vbox_tab.append(snapshot_list_box);
        
        page_stack.add_named(vbox_tab, "select");
        
        label = new Gtk.Label(_("Delete"));
        delete_box = new DeleteBox(this);
        delete_box.margin_start = 12;
        delete_box.margin_end = 12;
        delete_box.margin_top = 12;
        delete_box.margin_bottom = 12;
        page_stack.add_named(delete_box, "delete");
 
        label = new Gtk.Label(_("Finish"));
        delete_finish_box = new DeleteFinishBox(this);
        delete_finish_box.margin_start = 12;
        delete_finish_box.margin_end = 12;
        delete_finish_box.margin_top = 12;
        delete_finish_box.margin_bottom = 12;
        page_stack.add_named(delete_finish_box, "finish");
 
        create_actions();
 
        if (!embedded_mode)
            show();
 
        //go_first();
 
        tmr_init = Timeout.add(100, init_delayed);
 
        log_debug("DeleteWindow: DeleteWindow(): exit");
    }
    
    private bool init_delayed(){
 
        if (tmr_init > 0){
            Source.remove(tmr_init);
            tmr_init = 0;
        }
 
        go_first();
 
        return false;
    }
 
    private bool on_close_request(){
 
        return false; // close window
    }
    
    private void create_actions(){
        
        var hbox = new Gtk.Box(Gtk.Orientation.HORIZONTAL, 6);
        vbox_main.append(hbox);
         
        var bbox = new Gtk.Box (Gtk.Orientation.HORIZONTAL, 8);
        bbox.margin_start = 12;
        bbox.margin_end = 12;
        bbox.margin_top = 12;
        bbox.margin_bottom = 12;
        bbox.spacing = 6;
        bbox.hexpand = true;
        hbox.append(bbox);
        
        bbox_action = bbox;
 
        #if GTK3_18
            bbox.halign = Gtk.Align.CENTER; 
        #endif
        
        Gtk.SizeGroup size_group = null; //new Gtk.SizeGroup(SizeGroupMode.HORIZONTAL);
        
        // previous
        
        btn_prev = add_button(bbox, _("Previous"), "", size_group, null);
        btn_prev.get_style_context().add_class("btn-back");
        
        btn_prev.clicked.connect(()=>{
            go_prev();
        });
 
        // next
        
        btn_next = add_button(bbox, _("Next"), "", size_group, null);
        btn_next.get_style_context().add_class("btn-next");
 
        btn_next.clicked.connect(()=>{
            go_next();
        });
 
        // close
        
        btn_close = add_button(bbox, _("Close"), "", size_group, null);
        btn_close.get_style_context().add_class("btn-finish");
 
        btn_close.clicked.connect(()=>{
            if (embedded_mode)
                request_close();
            else
                this.destroy();
        });
 
        // hide
        
        btn_hide = add_button(bbox, _("Hide"), "", size_group, null);
        btn_hide.set_tooltip_text(_("Hide this window (files will be deleted in background)"));
        
        btn_hide.clicked.connect(()=>{
            if (embedded_mode)
                request_close();
            else
                this.destroy();
        });
    
        // cancel
        
        btn_cancel = add_button(bbox, _("Cancel"), "", size_group, null);
        btn_cancel.get_style_context().add_class("btn-cancel");
 
        btn_cancel.clicked.connect(()=>{
            // clear queue
            App.delete_list.clear();
            // kill current task
            if (App.delete_file_task != null){
                App.delete_file_task.stop(AppStatus.CANCELLED);
            }
            
            if (embedded_mode)
                request_close();
            else
                this.destroy(); // TODO: Show error page
        });
 
        btn_prev.hexpand = btn_next.hexpand = btn_cancel.hexpand = btn_close.hexpand = btn_hide.hexpand = true;
 
        action_buttons_set_initial_visibility(false);
    }
 
    private void action_buttons_set_initial_visibility(bool visible){
        
        btn_prev.visible = visible;
        btn_next.visible = visible;
        btn_hide.visible = visible;
        btn_close.visible = visible;
        btn_cancel.visible = visible;
    }
    
    // navigation
 
    private void go_first(){
        
        // set initial tab
        
        if ((App.delete_list.size == 0) && !App.thread_delete_running){
            set_page(Tabs.SNAPSHOT_LIST);
        }
        else {
            set_page(Tabs.DELETE);
        }
 
        initialize_tab();
    }
    
    private void go_prev(){
        switch(current_page){
        case Tabs.SNAPSHOT_LIST:
        case Tabs.DELETE:
            break;
        case Tabs.DELETE_FINISH:
            break;
        }
 
        initialize_tab();
    }
 
    private void go_next(){
        if (!validate_current_tab()){
            return;
        }
 
        switch(current_page){
        case Tabs.SNAPSHOT_LIST:
            App.delete_list = snapshot_list_box.selected_snapshots();
            set_page(Tabs.DELETE);
            break;
 
        case Tabs.DELETE:
            set_page(Tabs.DELETE_FINISH);
            break;
 
        case Tabs.DELETE_FINISH:
            if (embedded_mode)
                request_close();
            else
                destroy();
            break;
        }
 
        initialize_tab();
    }
 
    private void initialize_tab(){
 
        if (current_page < 0){
            return;
        }
 
        log_msg("");
        log_debug("page: %d".printf(current_page));
 
        action_buttons_set_initial_visibility(true);
 
        switch(current_page){
        case Tabs.DELETE:
            btn_prev.hide();
            btn_next.hide();
            btn_close.hide();
            btn_hide.show();
            btn_cancel.show();
            break;
 
        case Tabs.SNAPSHOT_LIST:
            btn_prev.show();
            btn_next.show();
            btn_close.show();
            btn_hide.hide();
            btn_cancel.hide();
            btn_prev.sensitive = false;
            btn_next.sensitive = true;
            btn_close.sensitive = true;
            break;
 
        case Tabs.DELETE_FINISH:
            btn_prev.hide();
            btn_next.hide();
            btn_close.show();
            btn_hide.hide();
            btn_cancel.hide();
            break;
        }
 
        switch(current_page){
        case Tabs.SNAPSHOT_LIST:
            snapshot_list_box.refresh();
            break;
        case Tabs.DELETE:
            success = delete_box.delete_snapshots();
            go_next();
            break;
        case Tabs.DELETE_FINISH:
            delete_finish_box.update_message(success);
            wait_and_close_window(1000, this);
            break;
        }
    }
 
    private bool validate_current_tab(){
        switch(current_page){
        case Tabs.SNAPSHOT_LIST:
            if (snapshot_list_box.selected_snapshots().size == 0){
                gtk_messagebox(
                    _("No Snapshots Selected"),
                    _("Select snapshots to delete"),
                    this, false);
                return false;
            }
            else{
                return true;
            }
 
        default:
            return true;
        }
    }
 
    private void set_page(int page) {
        current_page = page;
        switch (page) {
            case Tabs.SNAPSHOT_LIST:
                page_stack.set_visible_child_name("select");
                break;
            case Tabs.DELETE:
                page_stack.set_visible_child_name("delete");
                break;
            case Tabs.DELETE_FINISH:
                page_stack.set_visible_child_name("finish");
                break;
        }
    }
 
    public enum Tabs{
        SNAPSHOT_LIST = 0,
        DELETE = 1,
        DELETE_FINISH = 2
    }
 
    public Gtk.Widget detach_root_widget() {
        set_child(null);
        return vbox_main;
    }
 
    // ── Icon theme support ─────────────────────────────────────────────────
    private Gee.ArrayList<Gtk.Image> themed_img_list = new Gee.ArrayList<Gtk.Image>();
    private Gee.ArrayList<string>    themed_img_name = new Gee.ArrayList<string>();
    private Gee.ArrayList<int>       themed_img_size = new Gee.ArrayList<int>();
 
    private Gtk.Image themed_icon(string icon_name, int size) {
        var img = IconManager.lookup_image(icon_name, size);
        themed_img_list.add(img);
        themed_img_name.add(icon_name);
        themed_img_size.add(size);
        return img;
    }
 
    public void reload_themed_icons() {
        for (int i = 0; i < themed_img_list.size; i++) {
            var img  = themed_img_list[i];
            var name = themed_img_name[i];
            var sz   = themed_img_size[i];
            var pix  = IconManager.lookup(name, sz);
            if (pix != null) {
                img.set_from_pixbuf(pix);
            } else {
                img.set_from_icon_name(name);
            }
        }
    }
 
}