AppGtk.vala

Go to the documentation of this file.

/*
 * AppGtk.vala
 *
 * Copyright 2012-2018 Tony George <teejeetech@gmail.com>
 * Copyright 2025-2026 Calogero Scarnà — BastionGuard Backup
 *
 * GPL-2.0-or-later
 */
 
using GLib;
using Gtk;
using Gee;
using Json;
 
using TeeJee.Logging;
using TeeJee.FileSystem;
using TeeJee.JsonHelper;
using TeeJee.ProcessHelper;
using TeeJee.GtkHelper;
using TeeJee.System;
using TeeJee.Misc;
 
public Main App;
public const string AppName = "BastionGuard Backup-gtk";
public const string AppShortName = "bastionguard-backup";
public const string AppVersion = Constants.VERSION;
public const string AppAuthor = "BastionGuard™";
public const string AppAuthorEmail = "info@bastionguard.eu";
 
const string GETTEXT_PACKAGE = "bastionguard-backup";
const string BASTIONGUARD_RECOVERY_FLAG = "bastionguard.recovery=1";
const string LOCALE_DIR = "/usr/share/locale";
 
extern void exit(int exit_code);
 
public class AppGtk : GLib.Object {
 
    public static int main (string[] args) {
 
        set_locale();
 
        // Rileva --recovery o parametro kernel bastionguard.recovery=1
        bool recovery_mode = false;
        foreach (var arg in args) {
            if (arg == "--recovery") { recovery_mode = true; break; }
        }
        if (!recovery_mode && is_kernel_recovery_boot()) {
            recovery_mode = true;
        }
 
        if (args.length > 1) {
            switch (args[1].down()) {
                case "--help":
                case "--h":
                case "-h":
                    stdout.printf(help_message());
                    return 0;
                case "--version":
                    stdout.printf(version_message());
                    return 0;
            }
        }
 
        Main.setup_env();
 
        Gtk.init();
 
        GTK_INITIALIZED = true;
 
        init_tmp();
 
        check_if_admin();
 
        App = new Main(args, true);
 
        // In recovery mode: imposta app_mode così live_system() ritorna false
        // e tutte le funzioni (Crea, Ripristina, Wizard) restano disponibili
        if (recovery_mode) {
            App.app_mode = "recovery";
        }
 
        parse_arguments(args);
        App.initialize();
        start_application(recovery_mode);
 
        App.exit_app();
 
        return 0;
    }
 
    private static void set_locale() {
        log_debug("setting locale...");
        Intl.setlocale(GLib.LocaleCategory.MESSAGES, "bastionguard-backup");
        Intl.textdomain(GETTEXT_PACKAGE);
        Intl.bind_textdomain_codeset(GETTEXT_PACKAGE, "utf-8");
        Intl.bindtextdomain(GETTEXT_PACKAGE, LOCALE_DIR);
    }
 
    public static bool parse_arguments(string[] args) {
        for (int k = 1; k < args.length; k++) {
            switch (args[k].down()) {
            case "--debug":
                LOG_DEBUG = true;
                break;
            case "--recovery":
                // già gestito sopra
                break;
            default:
                log_error(_("Unknown option") + ": %s".printf(args[k]));
                log_msg(help_message());
                App.exit_app(1);
                return false;
            }
        }
        return true;
    }
 
    private static string version_message() {
        return "%s %s\n".printf(AppName, AppVersion);
    }
 
    public static string help_message() {
        string msg = "\n%s v%s by BastionGuard (%s)\n".printf(AppName, AppVersion, AppAuthorEmail);
        msg += "\n";
        msg += _("Syntax") + ": bastionguard-backup-gtk [options]\n";
        msg += "\n";
        msg += _("Options") + ":\n";
        msg += "\n";
        msg += "  --debug      " + _("Print debug information") + "\n";
        msg += "  --recovery   " + _("Start in recovery mode") + "\n";
        msg += "  --h[elp]     " + _("Show all options") + "\n";
        msg += "  --version    " + _("Print version number") + "\n";
        msg += "\n\n";
        msg += "\n%s\n".printf(_("Run 'bastionguard-backup' for the command-line version of this tool"));
        return msg;
    }
 
    public static void check_if_admin() {
        if (!user_is_admin()) {
            var msg = _("Admin access is required to backup and restore system files.") + "\n";
            msg += _("Please re-run the application as admin (using 'sudo' or 'su')");
            log_error(msg);
            string title = _("Admin Access Required");
            gtk_messagebox(title, msg, null, true);
            exit(1);
        }
    }
 
    public static void start_application(bool recovery_mode = false) {
 
        var window = new MainWindow();
        var loop = new GLib.MainLoop(null, false);
        window.close_request.connect(() => { loop.quit(); return false; });
 
        // Mostra dialog recovery DOPO che la finestra è pronta
        if (recovery_mode) {
            window.present();
            BastionGuardRecovery.show_recovery_banner(window);
        } else {
            // Controlla se c'è BastionGuardBackup da importare
            ImportDialog.check_and_show_if_needed(window);
            window.present();
        }
 
        loop.run();
    }
 
    // Controlla bastionguard.recovery=1 in /proc/cmdline
    private static bool is_kernel_recovery_boot() {
        try {
            string cmdline;
            FileUtils.get_contents("/proc/cmdline", out cmdline);
            return BASTIONGUARD_RECOVERY_FLAG in cmdline;
        } catch {
            return false;
        }
    }
}