BootOptionsBox.vala

Go to the documentation of this file.

/*
 * BootOptionsBox.vala
 */
 
using Gtk;
using Gee;
 
using TeeJee.Logging;
using TeeJee.FileSystem;
using TeeJee.JsonHelper;
using TeeJee.ProcessHelper;
using TeeJee.GtkHelper;
using TeeJee.System;
using TeeJee.Misc;
 
class BootOptionsBox : Gtk.Box{
    
    private Gtk.Box option_box;
    private Gtk.ComboBoxText cmb_grub_dev;
    private Gee.ArrayList<Device?> grub_devices = new Gee.ArrayList<Device?>();
 
    private Gtk.CheckButton chk_reinstall_grub;
    private Gtk.CheckButton chk_update_initramfs;
    private Gtk.CheckButton chk_update_grub;
    private Gtk.Window parent_window;
 
    public BootOptionsBox (Gtk.Window _parent_window) {
 
        log_debug("BootOptionsBox: BootOptionsBox()");
        
        GLib.Object(orientation: Gtk.Orientation.VERTICAL, spacing: 6);
        parent_window = _parent_window;
        margin_top = 12;
        margin_bottom = 12;
        margin_start = 12;
        margin_end = 12;
 
        option_box = new Gtk.Box(Gtk.Orientation.VERTICAL, 6);
        append(option_box);
 
        add_bootloader_options();
        refresh_options();
 
        log_debug("BootOptionsBox: BootOptionsBox(): exit");
    }
 
    private void add_bootloader_options(){
        add_chk_reinstall_grub();
        
        var hbox = new Gtk.Box(Orientation.HORIZONTAL, 6);
        hbox.margin_start = 12;
        append (hbox);
 
        cmb_grub_dev = new Gtk.ComboBoxText();
        cmb_grub_dev.hexpand = true;
        hbox.append(cmb_grub_dev);
 
        cmb_grub_dev.changed.connect(()=>{
            save_grub_device_selection();
        });
 
        hbox = new Gtk.Box(Orientation.HORIZONTAL, 6);
        append (hbox);
        add_chk_update_initramfs(hbox);
        add_chk_update_grub(hbox);
    }
 
    private void add_chk_reinstall_grub(){
        var chk = new CheckButton.with_label(_("(Re)install GRUB2 on:"));
        chk.active = false;
        chk.set_tooltip_markup(_("Re-installs the GRUB2 bootloader on the selected device."));
        append (chk);
        chk_reinstall_grub = chk;
 
        chk.toggled.connect(()=>{
            cmb_grub_dev.sensitive = chk_reinstall_grub.active;
            App.reinstall_grub2 = chk_reinstall_grub.active;
            save_grub_device_selection();
        });
    }
 
    private void add_chk_update_initramfs(Gtk.Box hbox){
        var chk = new CheckButton.with_label(_("Update initramfs"));
        chk.active = false;
        chk.set_tooltip_markup(_("Re-generates initramfs for all installed kernels. This is generally not needed. Select this only if the restored system fails to boot."));
        hbox.append (chk);
        chk_update_initramfs = chk;
 
        chk.toggled.connect(()=>{
            App.update_initramfs = chk_update_initramfs.active;
        });
    }
 
    private void add_chk_update_grub(Gtk.Box hbox){
        var chk = new CheckButton.with_label(_("Update GRUB menu"));
        chk.active = false;
        chk.set_tooltip_markup(_("Updates the GRUB menu entries (recommended). This is safe to run and should be left selected."));
        hbox.append (chk);
        chk_update_grub = chk;
 
        chk.toggled.connect(()=>{
            App.update_grub = chk_update_grub.active;
        });
    }
 
    private void save_grub_device_selection(){
        App.grub_device = "";
        if (!App.reinstall_grub2){
            return;
        }
 
        int index = cmb_grub_dev.get_active();
        if ((index < 0) || (index >= grub_devices.size)){
            return;
        }
 
        Device? entry = grub_devices[index];
        if (entry != null){
            App.grub_device = entry.device;
        }
    }
 
    private void refresh_options(){
        refresh_cmb_grub_dev();
        
        chk_reinstall_grub.active = App.reinstall_grub2;
        cmb_grub_dev.sensitive = chk_reinstall_grub.active;
        chk_update_initramfs.active = App.update_initramfs;
        chk_update_grub.active = App.update_grub;
        
        chk_reinstall_grub.sensitive = true;
        chk_update_initramfs.sensitive = true;
        chk_update_grub.sensitive = true;
                
        if (App.mirror_system){
            chk_reinstall_grub.sensitive = false;
            chk_update_initramfs.sensitive = false;
            chk_update_grub.sensitive = false;
        }
        else if (App.snapshot_to_restore.distro.dist_id == "fedora"){
            chk_reinstall_grub.sensitive = false;
        }
    }
    
    private void refresh_cmb_grub_dev(){
        grub_devices.clear();
        cmb_grub_dev.remove_all();
 
        foreach(Device dev in Device.get_block_devices_using_lsblk()) {
            if ((dev.type != "disk") && (dev.type != "part")){
                continue;
            }
            if ((dev.fstype == "luks")||(dev.fstype == "lvm2")){
                continue;
            }
            if (dev.size_bytes < 10 * KB){
                continue;
            }
 
            grub_devices.add(dev);
            string text = (dev.type == "disk")
                ? _("%s (MBR)").printf(dev.description())
                : dev.description();
            cmb_grub_dev.append_text(text);
        }
 
        cmb_grub_dev_select_default();
    }
 
    private void cmb_grub_dev_select_default(){
        if (cmb_grub_dev == null){
            return;
        }
        
        log_debug("BootOptionsBox: cmb_grub_dev_select_default()");
        
        if (App.grub_device.length == 0){
            cmb_grub_dev.active = -1;
            return;
        }
 
        int active = -1;
        for (int i = 0; i < grub_devices.size; i++){
            Device? dev_iter = grub_devices[i];
            if ((dev_iter != null) && (dev_iter.device == App.grub_device)){
                active = i;
                break;
            }
        }
 
        cmb_grub_dev.active = active;
        log_debug("BootOptionsBox: cmb_grub_dev_select_default(): exit");
    }
}